home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Night Owl 6
/
Night Owl's Shareware - PDSI-006 - Night Owl Corp (1990).iso
/
001a
/
tt20.zip
/
GEMAIL.SCR
next >
Wrap
Text File
|
1991-09-01
|
3KB
|
115 lines
; TurboTerm! v2.0 Script File
;
; Script : GEMAIL.SCR - captures waiting GEMail.
; Created: 08/17/91 20:40
; Author : Brian S. Dunworth
;
; This script makes use of several of TurboTerm's script
;
; *Note: The COMMENT lines will write comments into the current
; USAGE log if it is active during the connect. If the
; USAGE log is inactive, the line will be ignored.
;
;
;------------------------------------------------------------------
;
; first, set up a conditional statement to check for our EMail...
;
WHEN 1 "You have" GOTO MAIL
;
; ..if we have letters waiting, we'll execute the MAIL pr
;
;
; -------------------------------
; Logon
; -------------------------------
WAIT 2
SEND "HHH"
;
; Here, we switch the duplex, so that anyone looking over
; our shoulder won't see our password being entered.
;
DUPLEX FULL
WAITFOR "U#=" SEND "{PASSWORD}" TIMEOUT 10
DUPLEX HALF
;
; -------------------------------
; GEMail Main Procedure
; -------------------------------
;
WAITFOR "tinue?" SEND "{Enter}" TIMEOUT 60
;
; if we get here, there was no mail waiting, so deactivate the
; conditional...
;
WHEND 1
;
;
; Capture list of new files
;
:BOARDS
WAITFOR "P 1?" SEND "m615;3" TIMEOUT 60
WRITE "Capturing IBM RT new files list"
LOGNAME IBMFILES.NEW
COMMENT "Capturing IBM RT file listing"
WAITFOR "Library?" SEND "11" TIMEOUT 60
LOG ON
WAITFOR "Library?" GOSUB DONELOG TIMEOUT 32000
SEND "exit"
;
; Capture messages
;
WAITFOR "P 615?" SEND "m400;7" TIMEOUT 60
WRITE "Scanning LiveWire Board"
WAITFOR "1 ?" SEND "scr 0" TIMEOUT 100
WAITFOR "1 ?" SEND "bro nor" TIMEOUT 30
LOGNAME LIVEWIRE.TXT
COMMENT "Capturing LiveWire BB Messages"
LOG ON
WAITFOR "1 ?" GOSUB DONELOG TIMEOUT 32000
;
; Log off GEnie and exit TurboTerm
;
SEND "exit"
WAITFOR "P 400?" SEND "bye" TIMEOUT 90
;
WAITFOR "NO CARRIER" GOTO BYEBYE TIMEOUT 100
;
END
;
;
; -------------------------------
; GEMail Script Subroutines
; -------------------------------
;
; Letters waiting
:MAIL
;
; If we got here, there was EMail waiting for us...
;
WHEND 1
;
WRITE "Capturing waiting EMail"
WAITFOR "tinue?" SEND "m200;9" TIMEOUT 60
WAITFOR "Command?" SEND "list" TIMEOUT 60
LOGNAME EMAIL.TXT
COMMENT "Capturing EMail"
LOG ON
WAITFOR "Command?" GOSUB DONELOG TIMEOUT 32000
SEND "exi"
WAITFOR "P 200?" SEND "top" TIMEOUT 15
GOTO BOARDS
;
:DONELOG
; this small subroutine does nothing more than turn OFF the current
; log file. It is called a few times during this script...
;
LOG OFF
RETURN
;
:BYEBYE
; This procedure will exit TurboTerm, and return to the DOS prompt.
;
EXIT_TT
;